Stata 绘制堆积面积图 —— 新冠肺炎疫情:现存确诊、治愈和死亡人数

Stata 绘制堆积面积图 —— 新冠肺炎疫情:现存确诊、治愈和死亡人数

今天继续给大家带来一个小案例,昨天的是 ggplot2 的案例,今天的是个 Stata 的绘图案例,示例数据和代码都能从知识星球上下载。

首先导入数据并进行一些整理:

1
2
3
4
5
6
7
8
9
10
11
12
clear all
* 读入数据
import delimited using data-tT2vz.csv, clear varnames(1)
gen 日期 = date(date, "YMD")
format 日期 %tdCY-N-D
ren currentcases 现存确诊
ren recovered 治愈
ren deaths 死亡
order 日期 现存确诊 治愈 死亡
drop date
drop in -1
destring, replace

然后是生成绘图需要的一些变量:

1
2
3
4
5
6
7
8
* 基线
gen base = 0
* 治愈 + 现存确诊
gen 治愈_现存确诊 = 治愈 + 现存确诊
gen 死亡_治愈_现存确诊 = 死亡 + 治愈 + 现存确诊
* 查看首尾两天对应的数值日期
di date("2020-01-22", "YMD")
di date("2020-03-11", "YMD")

绘图:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
tw ///
rarea 现存确诊 base 日期, fc("95 144 161") ///
c("95 144 161") fintensity(inten80) lw(vvthin) || ///
rarea 治愈_现存确诊 现存确诊 日期, fc("180 209 132") ///
c("180 209 132") fintensity(inten80) lw(vvthin) || ///
rarea 死亡_治愈_现存确诊 治愈_现存确诊 日期, fc("122 118 123") ///
c("122 118 123") fintensity(inten80) lw(vvthin) ||, ///
leg(order(1 "现存确诊" 2 "治愈" 3 "死亡") pos(11) ring(0)) ///
title("冠状病毒 COVID-19 的全球疫情", size(*1.5) ///
justification(left) bexpand) ///
subtitle("这个图展示了新型冠状病毒 COVID-19 疫情的全局分布," ///
"包括现存确诊人数、已治愈人数和死亡人数。", ///
justification(left) bexpand) ///
caption("数据来源:约翰·霍普金斯大学 | 绘制:TidyFriday", ///
size(*0.8)) ///
xti("") xla(21935(10)21983) ///
xsc(range(21935 21985) extend) ///
graphr(margin(medlarge)) ///
text(20000 21964 "现存确诊", color(black) size(*1.2)) ///
text(63000 21972 "已经治愈", color(black) size(*1.2)) ///
text(85000 21968 "死亡", color(black) size(*1.2))

知识星球附件链接:https://t.zsxq.com/ByRvJmI

#

评论

Your browser is out-of-date!

Update your browser to view this website correctly. Update my browser now

×