如何使用 Stata 绘制粤港澳大湾区的地图？

最近有培训班的小伙伴需要使用 Stata 绘制粤港澳湾区的地图，所以今天就介绍下如何使用 Stata 绘制。

为了方便大家使用，我给大家准备了下面的数据：

城市级别：
区县级别：

城市地图

展示粤港澳大湾区的区位我们通常使用广东地图 + 港澳地图：

粤港澳大湾区区位图

绘图代码为：

use yga_db.dta, clear
gen wq = inlist(substr(市, 1, 6), "香港", "澳门", "广州", "深圳", "珠海") | inlist(substr(市, 1, 6), "佛山", "惠州", "东莞", "中山", "江门", "肇庆")
gen group = 1 if wq
replace group = 2 if inlist(substr(市, 1, 6), "湛江", "茂名", "阳江")
replace group = 3 if inlist(substr(市, 1, 6), "汕尾", "揭阳", "汕头", "潮州")
replace group = 4 if inlist(substr(市, 1, 6), "云浮", "清远", "河源", "梅州", "韶关")
label def group 1 "粤港澳湾区" 2 "粤西地区" 3 "粤东地区" 4 "北部地区"
label val group group
save yga_db2.dta, replace

spmap group using yga_coord.dta, id(ID) ///
 clmethod(custom) clbreaks(0 1 2 3 4) ///
 fcolor("112 154 225" "254 212 57" "213 228 162" "138 145 151") ///
 leg(order(2 "粤港澳湾区" 3 "粤西地区" 4 "粤东地区" 5 "北部地区") pos(4) size(*1.5)) ///
 ocolor("white" ...) osize(vthin ...) ///
 point(data(yga_db2.dta) x(x) y(y) ///
  shape(Oh Dh Th Sh) by(group) ///
  size(*0.5 ...) osize(*1.2 ...)) ///
 label(data(yga_db2.dta) x(x) y(y) ///
  label(市) gap(*1.8) pos(6) length(6)) ///
 graphr(margin(medium)) ///
 ti("粤港澳大湾区区位图", size(*1.1) pos(11)) ///
 subti("粤港澳大湾区地处我国沿海开放前沿，以泛珠三角区域为广阔发展腹地，在“一带一路”建设中具有重要地" "位。交通条件便利，拥有香港国际航运中心和吞吐量位居世界前列的广州、深圳等重要港口，以及香港、广" "州、深圳等具有国际影响力的航空枢纽，便捷高效的现代综合交通运输体系正在加速形成。", size(*0.8) pos(11)) ///
 caption("绘制：微信公众号 RStata", size(*0.8))

如果只绘制粤港澳湾区地图可以使用 if 进行筛选绘制：

粤港澳大湾区

绘图代码为：

* 只绘制粤港澳大湾区
encode 市, gen(city)
tab city if wq, nolabel
spmap city using yga_coord.dta if wq, id(ID) ///
 clmethod(custom) clbreaks(0 1 2 4 5 6 11 13 17 18 19 23) ///
 fcolor("254 212 57" "112 154 225" "138 145 151" "210 175 129" "253 116 70" "213 228 162" "25 126 192" "240 92 59" "70 115 46" "113 208 245" "55 3 53") ///
 leg(off) ///
 ocolor("white" ...) osize(vthin ...) ///
 point(data(yga_db2.dta) x(x) y(y) ///
  size(*0.5 ...) osize(*1.2 ...) ///
  select(keep if wq) shape(Oh)) ///
 label(data(yga_db2.dta) x(x) y(y) ///
  label(市) gap(*1.8) pos(6) length(6) ///
  select(keep if wq)) ///
 graphr(margin(medium)) ///
 ti("粤港澳大湾区包含的城市", size(*1.1) pos(11)) ///
 subti("粤港澳大湾区包括香港特别行政区、澳门特别行政区和广东省广州市、深圳市、珠海市、佛山市、惠" "州市、东莞市、中山市、江门市、肇庆市（以下称珠三角九市），总面积 5.6 万平方公里，2017年末" "总人口约7000万人，是我国开放程度最高、经济活力最强的区域之一，在国家发展大局中具有重要战" "略地位。", size(*0.8) pos(11)) ///
 caption("绘制：微信公众号 RStata", size(*0.8))

上面绘制的都是填充地图，如果想绘制描点地图可以使用 point() 选项，这里使用 2013 年工企业数据的分布为例展示：

描点地图

绘图代码为：

* 合并工企业的点和城市的质心
use yga_db2.dta, clear
keep x_centroid y_centroid 市 wq
keep if wq
gen centroid = 1
ren x_centroid 经度
ren y_centroid 纬度
append using "2013年粤港澳大湾区工企业数据.dta"
replace centroid = 0 if missing(centroid)
save 2013年粤港澳大湾区工企业数据2.dta, replace

use yga_db2.dta, clear
encode 市, gen(city)
tab city if wq, nolabel
tab city if wq
spmap city using yga_coord.dta if wq, id(ID) ///
 clmethod(custom) clbreaks(0 1 2 4 5 6 11 13 17 18 19 23) ///
 fcolor("254 212 57" "112 154 225" "138 145 151" "210 175 129" "253 116 70" "213 228 162" "25 126 192" "240 92 59" "70 115 46" "113 208 245" "55 3 53") ///
 leg(order(2 "东莞" 3 "中山" 4 "佛山" 5 "广州" 6 "惠州" 7 "江门" 8 "深圳" 9 "澳门" 10 "珠海" 11 "肇庆" 12 "香港") size(*1.2) pos(4) col(2)) ///
 ocolor("white" ...) osize(vthin ...) ///
 point(data(2013年粤港澳大湾区工企业数据2.dta) ///
  x(经度) y(纬度) by(centroid) ///
  size(*0.5 ...) osize(*1.2 ...) ///
  shape(p Oh) fcolor(gray%80 white)) ///
 label(data(yga_db2.dta) x(x) y(y) ///
  label(市) gap(*1.8) pos(6) length(6) ///
  select(keep if wq)) ///
 graphr(margin(medium)) ///
 ti("粤港澳大湾区工企业分布", size(*1.1) pos(11)) ///
 subti("数据来源：2013 年中国工业企业数据库", size(*0.8) pos(11)) ///
 caption("绘制：微信公众号 RStata", size(*0.8))

区县地图

如果大家需要绘制区县级地图可以使用区县的那几个文件，比不过还得结合着城市的数据来使用：

区县地图

use yga_county_db.dta, clear
gen wq = inlist(substr(市, 1, 6), "香港", "澳门", "广州", "深圳", "珠海") | inlist(substr(市, 1, 6), "佛山", "惠州", "东莞", "中山", "江门", "肇庆")
gen group = 1 if wq
replace group = 2 if inlist(substr(市, 1, 6), "湛江", "茂名", "阳江")
replace group = 3 if inlist(substr(市, 1, 6), "汕尾", "揭阳", "汕头", "潮州")
replace group = 4 if inlist(substr(市, 1, 6), "云浮", "清远", "河源", "梅州", "韶关")
label def group 1 "粤港澳湾区" 2 "粤西地区" 3 "粤东地区" 4 "北部地区"
label val group group
save yga_county_db2.dta, replace

spmap group using yga_county_coord.dta, id(ID) ///
 clmethod(custom) clbreaks(0 1 2 3 4) ///
 fcolor("112 154 225" "254 212 57" "213 228 162" "138 145 151") ///
 leg(order(2 "粤港澳湾区" 3 "粤西地区" 4 "粤东地区" 5 "北部地区") pos(4) size(*1.5)) ///
 ocolor("white" ...) osize(vvthin ...) ///
 point(data(yga_db2.dta) x(x) y(y) ///
  shape(Oh Dh Th Sh) by(group) ///
  size(*0.5 ...) osize(*1.2 ...)) ///
 label(data(yga_db2.dta) x(x) y(y) ///
  label(市) gap(*1.8) pos(6) length(6)) ///
 line(data(yga_line_coord.dta) by(_ID) ///
  color(black ...) size(vthin)) ///
 graphr(margin(medium)) ///
 ti("粤港澳大湾区区位图", size(*1.1) pos(11)) ///
 subti("粤港澳大湾区地处我国沿海开放前沿，以泛珠三角区域为广阔发展腹地，在“一带一路”建设中具有重要地" "位。交通条件便利，拥有香港国际航运中心和吞吐量位居世界前列的广州、深圳等重要港口，以及香港、广" "州、深圳等具有国际影响力的航空枢纽，便捷高效的现代综合交通运输体系正在加速形成。", size(*0.8) pos(11)) ///
 caption("绘制：微信公众号 RStata", size(*0.8))

单独绘制粤港澳大湾区的 11 个城市也是使用 if 进行筛选：

湾区区县地图

use yga_county_db2.dta, clear
encode 市, gen(city)
tab city if wq, nolabel
spmap city using yga_county_coord.dta if wq, id(ID) ///
 clmethod(custom) clbreaks(0 1 2 4 5 6 11 13 17 18 19 23) ///
 fcolor("254 212 57" "112 154 225" "138 145 151" "210 175 129" "253 116 70" "213 228 162" "25 126 192" "240 92 59" "70 115 46" "113 208 245" "55 3 53") ///
 leg(off) ///
 ocolor("white" ...) osize(vthin ...) ///
 point(data(yga_db2.dta) x(x) y(y) ///
  size(*0.5 ...) osize(*1.2 ...) ///
  select(keep if wq) shape(Oh)) ///
 label(data(yga_db2.dta) x(x) y(y) ///
  label(市) gap(*1.8) pos(6) length(6) ///
  select(keep if wq)) ///
 graphr(margin(medium)) xsize(9) ysize(6) ///
 ti("粤港澳大湾区包含的城市", size(*1.1) pos(11)) ///
 subti("粤港澳大湾区包括香港特别行政区、澳门特别行政区和广东省广州市、深圳市、珠海市、佛山市、惠州市" "、东莞市、中山市、江门市、肇庆市（以下称珠三角九市），总面积 5.6 万平方公里，2017年末总人口约" "7000万人，是我国开放程度最高、经济活力最强的区域之一，在国家发展大局中具有重要战略地位。", size(*0.8) pos(11)) ///
 caption("绘制：微信公众号 RStata", size(*0.8))

点击这里跳转到 RStata 短书平台获取附件：如何使用 Stata 绘制粤港澳大湾区的地图？

城市地图

区县地图

相关文章

评论